XSL（可扩展样式表语言）是对CSS的一种扩展，功能比CSS强大得多。XML链接是在HTML链接的功能之上加以扩展，可以支持更为复杂的链接，通过XML链接，不仅可以在XML文件之间建立链接，还可以建立其他类型数据之间的链接，其规范分为三个部分：XLink语言，XPointer语言和XML Base.
XML标准体系中还有其他很多技术，比如针对DTD的不足而提出的XML Schema,对XML文档进行结构话处理的DOM等，由于篇幅的关系，在这就不一一列举，不熟悉的请参考有关书籍。
好了，现在让我们开始进入正题——对XML的操作。首先，请保证您的电脑中有最新版本的MSXML，微软XML核心服务（MSXML）版本4.0提供了从Visual Basic6.0加载和存储XML文档的工具。若没有，请到http://msdn.microsoft.com/xml/default.asp中下载最新版本的MSXML，并安装在计算机上。在Visual Basic 6.0中使用Microsoft XML V4.0对象引用其他对象一样，首先在工程菜单中选择引用菜单项，选择Microsoft V4.0,单击OK,一切完成后就现在就可以在VB应用程序中添加XML对象了。如图： 
万事俱备，我们先用VB和MSXML的COM接口的DOM实现的一个例子来对XML操作进行初步的了解吧。
首先声明下面要用的几个对象的变量：
Dim tempdoc As DOMDocument
Dim tempnode As IXMLDOMNode
Dim tempelement As IXMLDOMElement
Dim tempattribute As IXMLDOMElement
Dim root As IXMLDOMElement
文档对象模型(DOM)使用了一系列相应的对象描述了XML文档的等级状态，DOMDocument类是一个描绘XML文档的DOM结构的MSXML类。DOMDocument类仅仅提供了很少的几个有用的属性和方法，例如：Load方法载入一个xml文件，loadxml方法将字符串作为xml数据添加到对象中。DOMDocument的xml属性返回文档的xml描述，可以显示这些返回值看看这些文档究竟是什么样子，也可以将它存储为一个文件，DOMDocument对象的documentElement属性表示文档数据的根结点，通常情况下操作XML文档都从这里开始。DOMDocument提供了几种创建新节点的方法。CreateElement方法为文档创建一个新的元素节点，其他创建节点的方法有createAttribute, createProcessingInstruction, 和 createTextNode，在这里就不一一介绍了。
IXMLDOMNode类描述了一个节点，该类提供了一系列用于搜索和操纵XML文档的属性和方法。selectSingleNode 方法用于搜索指定节点的后代，用于搜索指定节点路径的语言称为XPATH，XPATH非常棘手，本文就不详细说明其规范了。在IXMLDOMNode对象中，有许多有用的属性值：
attributes.节点属性集合
nodeName.节点的标记名
nodeTypeString.节点的类型
ownerDocument.返回DOMDocument对象包含的节点
text.表示节点包含的文本内容。如果该节点包含其他节点，那么text代表了所有节点的文本内容的组合。
xml.给出了节点的xml内容，例如："＜Email＞hongwanfu@yahoo.com＜/Email＞".
ChildNodes集合包含了节点的子节点。要给节点增加一个子节点，首先必须给使用DOMDocument对象的节点创建方法，然后将这个新建的节点加入到父节点的childNodes集合中。 ChildNodes集合包含了节点的子节点。要给节点增加一个子节点，首先必须给使用DOMDocument对象的节点创建方法，然后将这个新建的节点加入到父节点的childNodes集合中。
由于每个节点类型都有不同的访问方法和内容限制，有时候使用特定类型的节点要比使用通用 IXMLDOMNode 对象更容易。要做到这一点，需要使用 IXMLDOMElement 对象来处理 XML 数据元素和属性。正如元素可以包含 XML 数据文件中的子元素、文本、注释、处理说明、CDATA 部分和实体引用一样，IXMLDOMElement 对象也可以包含 IXMLDOMElement、IXMLDOMText、IXMLDOMComment、IXMLDOMProcessingInstruction、IXMLDOMCDATASection 和 IXMLDOMEntityReference 对象。可以通过使用 IXMLDOMElement 对象的 getAttribute 和 setAttribute 方法来访问属性；或者通过 IXMLDOMElement 对象的 attributes 属性，将属性作为 IXMLDOMNamedNodeMap 对象进行管理。有关使用这些方法和对象的详细信息，请参阅 MSXML 4.0 SDK Help。
接下来我们要做的是生成一个XML DOMDocument 对象 ：
Set tempdoc = New DOMDocument
生成根节点并把它设置为文件的根 ：
Set root = tempdoc.createElement("Personal")
Set tempdoc.documentElement = root
生成孩子节点添加到根节点上去，并且为这个节点设置一个属性 ：
Set tempnode = tempdoc.createNode(NODE_ELEMENT, "Web", "")
tempnode.Text = " http://hongwanfu.126.com "
root.appendChild tempnode
取得元素节点的接口，添加属性：
Set tempelement = tempnode
tempelement.setAttribute "Type", "Homepage"
最后，写XML文件：
Open "CreateXMLFile.xml" for output as #1
Print #1, root.XML
Close #1
下面就是上面程序生成的CreateXMLFile.xml文件的内容如图：
熟悉了如何用Visual Basic 6创建XML文件，接下来，我们将编写一个程序，使得程序开始运行时，程序从XML文件中加载数据，在程序运行结束时，将程序中的现行值存入XML文件中。
首先，建立一个名叫Personal.xml的文件：
＜?xml version="1.0" encoding="GB2312"?＞
＜个人信息＞
＜姓名＞洪万福＜/姓名＞
＜性别＞男＜/性别＞
＜出生日期＞1983年x月x日＜/出生日期＞
＜地址＞福建省厦门市集美大学水产学院新区270#＜/地址＞
＜邮编＞361021＜/邮编＞
＜QQ＞24948251＜/QQ＞
＜个人主页＞http://hongwanfu.126.com＜/个人主页＞
＜/个人信息＞
其中，encoding="GB2312"是为了防止显示中文时出现乱码。
接着，进入Visual Basic 6，建立7个Label和7个TextBox, 具体如图：
随后，编写如下代码：
Option Explicit
Private p_AppPath As String
Private Sub Form_Load()
' 获得程序运行目录
p_AppPath = App.Path
If Right$(p_AppPath, 1) ＜＞ "\" Then p_AppPath = p_AppPath & "\"
' 加载值
LoadValues
End Sub
Private Sub Form_Unload(Cancel As Integer)
' 保存现有的值
SaveValues
End Sub
Private Sub LoadValues()
Dim xml_document As DOMDocument
Dim values_node As IXMLDOMNode
' 载入文件
Set xml_document = New DOMDocument
xml_document.Load p_AppPath & "Personal.xml"
If xml_document.documentElement Is Nothing Then
Exit Sub
End If
'寻找节点
Set values_node = xml_document.selectSingleNode("个人信息")
' 读取各个节点的值
txtName.Text = GetNodeValue(values_node, "姓名", "???")
txtSex.Text = GetNodeValue(values_node, "性别", "???")
txtBirthday.Text = GetNodeValue(values_node, "出生日期", "???")
txtAddress.Text = GetNodeValue(values_node, "地址", "???")
txtZip.Text = GetNodeValue(values_node, "邮编", "???")
txtQQ.Text = GetNodeValue(values_node, "QQ", "???")
txtHomepage.Text = GetNodeValue(values_node, "个人主页", "???")
End Sub
' 返回各个节点的值
Private Function GetNodeValue(ByVal start_at_node As IXMLDOMNode, ByVal node_name As String, _
Optional ByVal default_value As String = "") As String
Dim value_node As IXMLDOMNode
Set value_node = start_at_node.selectSingleNode(".//" & node_name)
If value_node Is Nothing Then
GetNodeValue = default_value
Else
GetNodeValue = value_node.Text
End If
End Function
' 保存现有的值
Private Sub SaveValues()
Dim xml_document As DOMDocument
Dim values_node As IXMLDOMNode
' 建立XML文件
Set xml_document = New DOMDocument
Set values_node = xml_document.createElement("个人信息")
xml_document.appendChild values_node
CreateNode values_node, "姓名", txtName.Text
CreateNode values_node, "性别", txtSex.Text
CreateNode values_node, "出生日期", txtBirthday.Text
CreateNode values_node, "地址", txtAddress.Text
CreateNode values_node, "邮编", txtZip.Text
CreateNode values_node, "QQ", txtQQ.Text
CreateNode values_node, "个人主页", txtHomepage.Text
' 保存XML文件
xml_document.save p_AppPath & "Personal.xml"
End Sub
Private Sub CreateNode(ByVal parent As IXMLDOMNode, _
ByVal node_name As String, ByVal node_value As String)
Dim new_node As IXMLDOMNode
Set new_node = parent.ownerDocument.createElement(node_name)
new_node.Text = node_value
parent.appendChild new_node
End Sub
运行结果如下：
虽然，MSXML提供了从Visual Basic6.0加载和存储XML文档的工具，但是，对其的应用要求程序员对VB和MSXML的COM接口有一定的认识，所以，并不是得到很广泛的应用。
查看更多关于【VisualBasic】的文章
